Over the weekend I needed to see what was in my cache. I whipped up a quick script to list everything in cache and from there:
<cfscript>
writeOutput('<h2>CF Dude, What''s in the cache?</h2><div><a href="#cgi.script_name#">Reload</a><br><br></div>');
param name="url.do" default="";
switch (url.do) {
case "remove":
cacheRemove(url.item);
writeOutput("<div style='color: green; font-weight: bold'>Removed #url.item#</div>");
break;
case "view":
writeDump( var=cacheGet(url.item), label="Cache contents of: " & url.item, top=10 );
break;
case "meta":
writeDump( var=cacheGetMetadata(url.item), label="Metadata for: " & url.item );
break;
}
incache = cacheGetAllIds();
arraySort(incache,"textnocase");
</cfscript>
<cfoutput>
<h3>Cache IDs</h3>
<table cellspacing="4">
<cfloop array="#incache#" index="c">
<tr>
<td>#c#</td>
<td><a href="#cgi.script_name#?do=remove&item=#c#">remove</a></td>
<td><a href="#cgi.script_name#?do=view&item=#c#">view</a></td>
<td><a href="#cgi.script_name#?do=meta&item=#c#">meta</a></td>
</tr>
</cfloop>
</table>
<h3>Cache Properties</h3>
<cfdump var="#cacheGetProperties()#">
</cfoutput>
By: Katie McKinsey 04/04/2011 12:43 PM